通过 SignedInfo 元素计算的加密签名的有效性状态。

此状态是：

• valid — 如果签名是加密有效的。
• invalid — 如果摘要已在签名后更改。
• unknown — 如果尚未调用 verify() 方法。

注意：如果 digestStatus 无效，则不检查 identityStatus 和 referencesStatus，并会将其报告为 unknown。

签名证书的有效性状态。

该状态可以是：

• valid — 证书尚未过期，吊销检查和指向受信任的根证书的链接没有失败。
• unknown — 证书尚未过期，吊销检查没有失败，但没有链接到受信任的根证书。尚未验证状态时也会报告 unknown，不管是因为尚未调用 verify() 方法还是因为 SignedInfo 元素 (digestStatus) 的加密签名无效。
• invalid — 证书已过期或吊销检查失败。

无论证书是否被视为有效，使用 addCertificate() 方法添加的证书以及 revocationCheckSetting 和 useSystemTrustStore 属性的设置都可以进行更改。

注意：如果 identityStatus 无效，则不检查 referencesStatus，并会将其报告为 unknown。此外，当 identityStatus 为 unknown 时，不检查引用，除非 referencesValidationSetting 为 validOrUnknownIdentity

另请参见

import flash.security.XMLSignatureValidator;
 
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var identityResult:String = verifier.identityStatus;

SignedInfo 元素中引用的数据的有效性状态。

该状态可以是：

• valid — 如果所有引用都有效。
• invalid — 如果存在无效的引用。
• unknown - 如果未验证。在以下环境中引用可以保持未验证状态：
  • 尚未调用 verify() 方法
  • SignedInfo 元素的加密签名 (digestStatus) 无效。
  • 签名证书 (identityStatus) 无效
  • referencesValidationSetting 为 validIdentity（默认设置），且签名证书的 identityStatus 未知。
  • referencesValidationSetting 为 never。

重要说明：不验证外部资源，除非在签名文档内的 SignedInfo 元素中直接引用这些外部资源。不验证辅助引用所指的外部资源。例如，如果 XML 签名签署了一个 manifest 元素，则仅验证 manifest 元素自身的完整性。不检查 manifest 中列出的文件。

另请参见

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var dataResult:String = verifier.referencesStatus;

指定检查引用时所处的条件。

使用 ReferencesValidationSetting 类中定义的常量来设置此属性。这些设置包括：

• ReferencesValidationSetting.VALID_IDENTITY - 仅在签名证书有效且与受信任的根有联系时检查引用。这是默认设置。
• ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY - 如果签名证书有效，即使与受信任的根无联系，也会检查引用。
• ReferencesValidationSetting.NEVER - 从不检查引用。

对于以商业证书签署的签名，或当您以 addCertificate() 方法提供自己的证书作为受信任的锚记时，将使用默认设置 validIdentity。在已签名文档无论如何都会被拒绝时，此设置避免了检查引用有效性的开销。

对于以自签名证书签署的签名，将使用 validOrUnknownIdentity 设置。此设置使您可以验证已签名的数据未被更改，但无法确定签名者的身份。

此类验证对您的应用程序并不重要时，使用 never 设置可避免验证引用的开销。

另请参见

import flash.security.ReferencesValidationSetting;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;

指定如何检查证书吊销。

使用 RevocationSettings 类中定义的常量来设置此属性。这些设置包括：

• RevocationCheckSettings.NEVER — 不检查证书吊销。
• RevocationCheckSettings.BEST_EFFORT — 如果吊销信息可用且可以获取吊销状态，则检查证书吊销。如果无法明确确定吊销状态，则不拒绝该证书。
• RevocationCheckSettings.REQUIRED_IF_AVAILABLE — 如果证书包括吊销信息，则必须明确确定吊销状态以验证该证书。
• RevocationCheckSettings.ALWAYS_REQUIRED — 始终检查证书吊销。拒绝没有吊销信息的证书。

另请参见

签名证书的“公共名称”字段。

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var commonName:String = verifier.signerCN;

签名证书的“识别名称”字段。

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var distinguishedName:String = verifier.signerDN;

包含签名证书中列出的扩展密钥用法 OID 的数组。

每种扩展密钥用法均以数字 OID 形式进行报告。

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var extendedKeyOIDs:Array = verifier.signerExtendedKeyUsages;

包含签名证书的信任设置的数组。

信任设置是从系统和证书中嵌入的密钥用法 OID 中派生的。用作表示已识别的信任设置的字符串的常量在 SignerTrustSettings 类中定义。

unknown 或 invalid 证书的 signerTrustSettings 数组为空数组。

修改该数组不会更改证书信任设置。

另请参见

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate a signature...
  
 var certificateTrustedFor:Array = verifier.signerTrustSettings;

IURIDereferencer 实现。

尝试验证签名之前必须提供 IURIDereferencer 实现。

另请参见

import com.example.SignedMessageDereferencer; //A custom class implementing IURIDereferencer
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.uriDereferencer = new SignedMessageDereferencer();

指定使用系统信任存储中的证书来构建链。

如果为 true，则使用系统信任存储中的信任锚记作为受信任的根。默认情况下不使用系统信任存储。

var verifier:XMLSignatureValidator = new XMLSignatureValidator(); 
 verifier.useSystemTrustStore = true;

经过验证的 XML 签名的有效性状态。

验证 XML 签名的途径是验证 SignedInfo 元素的加密签名、签名证书以及 SignedInfo 元素中引用所指的数据。这些元素中每个元素的有效性分别由 digestStatus、identityStatus() 和 referencesStatus 属性进行报告。

XML 签名的有效性可以为 valid、invalid 或 unknown。整体状态取决于签名文件各个组件的验证状态：

• digestStatus — 通过 SignedInfo 元素计算的加密签名的有效性。
• identityStatus — 签名证书的有效性。
• referencesStatus - 签名 SignedInfo 元素中引用摘要的有效性。

由 validityStatus 属性报告的签名有效性可以为：

• valid - 如果 referencesStatus、digestStatus 和 identityStatus 全部为 valid。
• invalid - 如果其中任何一个状态为 invalid。
• unknown - 如果其中任何一个状态为 unknown。

另请参见

import flash.security.XMLSignatureValidator;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 //validate the signature...
  
 var validationResult:String = verifier.validityStatus;

创建 XMLSignatureValidator 对象。

在调用新对象的 verify() 方法之前必须设置 uriDereferencer 属性。

另请参见

import com.example.EnvelopedDereferencer; //Your custom IURIDereferencer implementation

//Create the object
var verifier:XMLSignatureValidator = new XMLSignatureValidator();

//Provide the IURIDerferencer
verifier.uriDereferencer = new EnvelopedDereferencer(xmlDoc);

//Set validation options
verifier.referencesValidationSetting = ReferencesValidationSetting.VALID_OR_UNKNOWN_IDENTITY;
verifier.revocationCheckSetting = RevocationCheckSettings.NEVER;
verifier.useSystemTrustStore = true;

//Add listeners to handle results
verifier.addEventListener(Event.COMPLETE, verificationComplete);
verifier.addEventListener(ErrorEvent.ERROR, verificationError);

添加 x509 证书以构建链。

添加的证书必须是 DER 编码的 x509 证书。

如果 trusted 参数为 true，则将证书视为信任锚记。

注意：XML 签名可能包括用于构建签名者的证书链的证书。XMLSignatureValidator 类使用这些证书构建链，但不作为受信任的根（默认情况下）。

参数

import flash.utils.ByteArray;
 
 var verifier:XMLSignatureValidator = new XMLSignatureValidator();
 var certificate:ByteArray = new ByteArray();
 
 var certFile:File = new File("certificate.cer");
 var certFileStream:FileStream = new FileStream();
 certFileStream.open(certFile, FileMode.READ);
 certFileStream.readBytes(certificate, 0, certFileStream.bytesAvailable);

 verifier.addCertificate(certificate, true);

验证指定的签名。

验证是异步进行的。验证成功完成时，XMLSignatureValidator 对象将调度 complete 事件，或者由于错误无法完成验证时将调用 error 事件。

无法取消验证过程。当验证过程正在进行时，对 verify() 方法的后续调用将失败。在当前验证检查完成后，可以再次调用 verify() 方法。

注意：由于 XMLSignatureValidator 只能实现 XML 签名语法和处理 W3C 建议的一个子集，因此无法验证所有有效的 XML 签名。

参数

import flash.filesystem.File;
import flash.filesystem.FileStream;
import com.example.SignedMessageDereferencer; //Your IURIDereferencer implementation
 
const xmlSignatureNS:Namespace = new Namespace( "http://www.w3.org/2000/09/xmldsig#" );

var verifier:XMLSignatureValidator = new XMLSignatureValidator();
verifier.uriDereferencer = new SignedMessageDereferencer();

var signatureFile:File = new File( "path/to/XMLSignatureDocument.xml" );
var sigFileStream:FileStream = new FileStream();
sigFileStream.open( signatureFile, FileMode.READ );

var xmlDoc:XML = XML( sigFileStream.readUTFBytes(sigFileStream.bytesAvailable) );
var xmlSig:XML = XML( xmlDoc..xmlSignatureNS::Signature );

verifier.verify( xmlSig );

在完成验证时调度。

complete 事件并不意味着签名有效。检查 XMLSignatureValidator 对象的 validityStatus 属性来确定签名验证的结果。

此事件具有以下属性：

private function verificationComplete(event:Event):void{
    var validator:XMLSignatureValidator = event.target as XMLSignatureValidator;
    trace("Digest status: " + validator.digestStatus);
    trace("Identity status: " + validator.identityStatus);
    trace("Reference status: " + validator.referencesStatus);
    trace("Signature status: " + validator.validityStatus);    
}

另请参见

由于错误而无法完成验证时调度。

此事件具有以下属性：

private function verificationError(event:ErrorEvent):void{
    trace("Verification error: " + event.text);                
}