指示此 XMLSocket 对象目前是否已连接。还可以通过为 connect 事件和 ioError 事件注册来检查连接是否成功。

另请参见

指示建立连接时需等待的毫秒数。

如果在指定时间内未成功建立连接，则连接失败。默认值是 20,000（20 秒）。

创建一个新的 XMLSocket 对象。若未指定参数，将创建一个最初处于断开状态的套接字。 若指定了参数，则尝试连接到指定的主机和端口。

注意：强烈建议使用不带参数的构造函数形式，并添加任意事件侦听器，然后使用 host 和 port 参数调用 connect 方法。此序列将确保所有事件侦听器工作正常。

另请参见

关闭由 XMLSocket 对象指定的连接。仅在服务器关闭连接时调度 close 事件；在调用 close() 方法时不调度该事件。

另请参见

使用指定的 TCP 端口建立到指定 Internet 主机的连接。

如果为 host 参数指定 null，则与调用 XMLSocket.connect() 的 文件所在的主机连接。例如，如果进行调用的文件是从 www.adobe.com 下载的，则将 host 参数指定为 null 表示您将连接到 www.adobe.com。

可以在包含 内容的 HTML 页中设置 object 和 embed 标签的 allowNetworking 参数，防止 SWF 文件使用此方法。

有关详细信息，请参阅以下部分：

• “安全性”一章（位于《ActionScript 3.0 编程》一书中）和有关 LiveDocs 的最新评论
• Flash Player 开发人员中心主题：安全性

参数

另请参见

将 object 参数中指定的 XML 对象或数据转换成字符串，并将其传输到服务器，后面跟有一个零 (0) 字节。如果 object 是一个 XML 对象，则该字符串是此 XML 对象的 XML 文本表示形式。发送操作是异步的；它将立即返回，但数据可能会以后传输。XMLSocket.send() 方法不返回指示数据是否成功传输的值。

如果不是使用 XMLSocket.connect() 将 XMLSocket 对象连接到服务器，则 XMLSocket.send() 操作失败。

参数

另请参见

在服务器关闭套接字连接时调度。仅在服务器关闭连接时调度 close 事件；在调用 XMLSocket.close() 方法时不调度该事件。

此事件具有以下属性：

在成功调用 XMLSocket.connect() 方法后调度。

此事件具有以下属性：

在发送或接收原始数据后调度。

此事件具有以下属性：

在出现输入/输出错误并导致发送或接收操作失败时调度。

此事件具有以下属性：

若对 XMLSocket.connect() 方法的调用尝试连接到调用方安全沙箱外部的服务器或低于 1024 的端口，则进行调度。

此事件具有以下属性：

另请参见

1. XMLSocketExample 构造函数创建名为 socket 的 XMLSocket 实例，并将 socket 传递给 ConfigureListeners()（如下所述），然后使用主机名“localhost”和端口号 8080 调用 connect() XMLSocket 的方法。
2. 随后调用 configureListeners() 方法，该方法为每个受支持的 XMLSocket 事件添加侦听器：
   • closeHandler()：侦听 close 事件，在网络连接关闭后调度该事件。
   • connectHandler()：侦听 connect 事件，在建立网络连接后调度该事件。
   • dataHandler()：侦听 data 事件，在 XMLSocket 每次接收新数据时调度该事件。
   • progressHandler()：侦听 progress 事件，已调用 send() 并且发送正在进行时调度该事件。
   • securityErrorHandler()：侦听 securityError 事件，如果试图使用错误的本地回放安全性设置或端口号低于 1024 的端口访问 XMLSocket，则调度该事件。
   • ioErrorHandler()：侦听 ioError 事件，仅当发送或接收数据的操作失败时，才会发生该事件。

注意：

• 您需要编译 SWF 文件并将“本地回放安全性”设置为“只访问网络”。
• 若要让本示例正常工作，需要一个在域上运行并使用 8080 端口的服务器。
• 如果运行的是 Flash Player 9.0.124.0 或更高版本，则需要在服务器上放置一个套接字策略文件，以允许建立从域到端口 8080 的套接字连接。有关提供套接字策略文件的信息，请参阅 Flash Player 开发人员中心主题：设置套接字策略文件服务器。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            if (hostName && port) {
                socket.connect(hostName, port);
            }
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}