让qmake像cmake一样自动查找python

晨曦之光 发布于 2012/05/08 10:16
阅读 724
收藏 1

本文是介绍qmake的,不过要以cmake编译嵌入python的C++程序开篇。

例子

简简单单,一个在C、C++中嵌入python的例子

#include "Python.h"
int main()
{
    Py_Initialize();
    PyRun_SimpleString("print \'Hello qmake!\'");
    Py_Finalize();
    return 0;
}

这个例子嵌入一个python解释器,执行一条python的print语句。程序运行结果:

"Hello qmake!"

如何编译

  • 编译本身很简单,我们只需要这样的一条命令:

g++ main.cpp -ID:\Python27\include D:\Python27\libs\python27.lib

让人郁闷的是,需要指定python的安装路径,而不同人安装路径和Python版本都可能不同,没办法直接写成脚本什么的了

cmake

如果使用cmake的话,我们只需要这样的工程文件

  • CMakeLists.txt

cmake_minimum_required(VERSION 2.8)
project(HELLO)
find_package(PythonLibs REQUIRED)
include_directories(${PYTHON_INCLUDE_DIRS})
add_executable(hello main.cpp)

然后运行

cmake .
make

就可以了,自始至终不需要我们指定python的路径。很不错哈

可是,我在用qmake而不是cmake啊,这可如何是好?

qmake

  • Linux 下:

由于qmake提供了pkg_config支持,在linux下,我们很容易写出下面的 xxx.pro 文件。

CONFIG  -= qt
CONFIG  += console
unix{
    CONFIG += link_pkgconfig
    PKGCONFIG += python
}

SOURCES += main.cpp
  • 在 Windows 下,可没有这么幸运了,pkg_config 没有市场。真要这么写么

win32{
    INCLUDEPATH += D:\\Python27\\include
    LIBS += D:\\Python27\\libs\python27.lib
}

不甘心!!

Windows下如何找到Python

不妨考虑我们开始的那个例子:这个程序运行时,如何找到Python的那些模块的呢?

  • 如果PYTHONHOME被设置,则使用
  • 否则,按照可执行程序所在目录向上搜索 (lib/os.py)
  • 否则,查找注册表

恩,对我们有用的1、3两项,不过在Windows下,环境变量用的也不多啊。那就只剩查注册表了

读取注册表?

翻遍qmake手册,没发现qmake提供操作注册表的功能;看看qmake源码,恩,还是没有 ...

怎么办,看来只能用其他程序,或者写个Windows默认支持的 .bat/.vbs/.js 脚本?

还好,有个 reg.exe 的程序可以使用,命令行下运行看看:

C:\> reg query HKLM\SOFTWARE\Python\PythonCore\2.7\InstallPath /ve

HKEY_LOCAL_MACHINE\SOFTWARE\Python\PythonCore\2.7\InstallPath
    (默认)    REG_SZ    D:\Python27\

恩看起来还不错,只要执行该命令,然后提取结果中REG_SZ后面的路径就可了。

可是还是有个可恶的2.7啊?其他人可能在用Python2.6或2.5,额,都查一遍好了:

最终的代码如下:

  • 将可能的版本号存入列表 PY_VERSIONS
  • 遍历这个列表,检查reg.exe的返回值,非0则跳过
  • 获取reg.exe的标准输出,用正则表达式提取路径到 PY_HOME 中
  • 判断 Python.h 是否存在,不存在则跳过
  • 将头文件路径和库文件分别加入到 INCLUDEPATH 和 LIBS 中
    • 注意,库文件分 PythonXX.lib 和 PythonXX_d.lib
  • 结束

win32:{
   PY_VERSIONS = 2.7 2.6 2.5 2.4
   for(PY_VERSION, PY_VERSIONS){
       system(reg query HKLM\\SOFTWARE\\Python\\PythonCore\\$$PY_VERSION\\InstallPath /ve) {
           PY_HOME = $$quote($$system(reg query HKLM\\SOFTWARE\\Python\\PythonCore\\$$PY_VERSION\\InstallPath /ve))
           PY_HOME ~= s/.*(\\w:.*)/\\1
           !exists($$PY_HOME\\include\\Python.h):next()
           INCLUDEPATH *= $$PY_HOME\\include
           PY_LIB_BASENAME = python$${PY_VERSION}
           PY_LIB_BASENAME ~= s/\\./
           CONFIG(debug, debug|release):PY_LIB_BASENAME = $${PY_LIB_BASENAME}_d
           LIBS *= $$PY_HOME\\libs\\$${PY_LIB_BASENAME}.lib
           message(Python$$PY_VERSION found at $$PY_HOME)
           break()
       }
   }
}
  • 恩,然后将这段代码加到 XXX.pro 文件即可。
  • 如果看着不爽,可以单独放到一个 XXX.pri 文件内,然后 include 进来。
  • 如果还不爽,可以单独放到一个 mypython.prf 的文件中,然后在.pro文件内使用 CONFIG += mypython



原文链接:http://blog.csdn.net/dbzhang800/article/details/6848090
加载中
返回顶部
顶部